-
Notifications
You must be signed in to change notification settings - Fork 6
/
flake.nix
256 lines (239 loc) · 7.33 KB
/
flake.nix
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
{
description = "https://github.com/internet4refugees/beherbergung.git development environment + package + deployment";
nixConfig.extra-substituters = ["https://cache.garnix.io"];
nixConfig.extra-trusted-public-keys = ["cache.garnix.io:CTFPyKSLcx5RMJKfLo5EEPUObbA78b0YQ2DTCJXqr9g="];
inputs = {
# use 21.11-small for fast security updates
nixpkgs.url = "github:NixOS/nixpkgs/nixos-21.11-small";
alejandra = {
url = "github:kamadorueda/alejandra/1.1.0";
inputs.nixpkgs.follows = "nixpkgs";
};
sops-nix = {
url = "github:Mic92/sops-nix";
inputs.nixpkgs.follows = "nixpkgs";
};
dns = {
url = "github:kirelagin/dns.nix";
inputs.nixpkgs.follows = "nixpkgs";
};
mvn2nix = {
url = "github:fzakaria/mvn2nix";
inputs.nixpkgs.follows = "nixpkgs";
};
nixos-shell = {
url = "github:Mic92/nixos-shell";
inputs.nixpkgs.follows = "nixpkgs";
};
naersk = {
url = "github:nix-community/naersk";
inputs.nixpkgs.follows = "nixpkgs";
};
fenix = {
url = "github:nix-community/fenix";
inputs.nixpkgs.follows = "nixpkgs";
};
deadnix = {
url = "github:astro/deadnix";
inputs.nixpkgs.follows = "nixpkgs";
inputs.naersk.follows = "naersk";
inputs.fenix.follows = "fenix";
};
};
outputs = {
self,
nixpkgs,
sops-nix,
dns,
alejandra,
mvn2nix,
nixos-shell,
deadnix,
...
}: let
system = "x86_64-linux";
pkgs = import nixpkgs {inherit system;};
inherit (pkgs) lib;
commonAttrs = {
system = "x86_64-linux";
extraArgs = {
flake = self;
inherit system dns;
};
};
commonModules = [
];
linters = [
# TODO: switch to alejandra from nixpkgs in 22.05
alejandra.defaultPackage.${system}
pkgs.treefmt
pkgs.clj-kondo
pkgs.shfmt
pkgs.nodePackages.prettier
];
in rec {
legacyPackages.${system} = lib.mergeAttrs pkgs {
#nixos-deploy = import ./tools/deploy.nix { inherit pkgs; };
};
packages.${system} = {
devShell = self.devShell.${system}.inputDerivation;
updateBackendDeps = pkgs.callPackage ./backend/nix/tools/updated-deps.nix {
inherit (mvn2nix.legacyPackages.${system}) mvn2nix;
};
beherbergung-backend = pkgs.callPackage ./backend/nix/beherbergung-backend.nix {
inherit (mvn2nix.legacyPackages.${system}) buildMavenRepositoryFromLockFile;
inherit pkgs;
};
beherbergung-fullstack = self.packages.${system}.beherbergung-backend.override {
patchPublic = self.packages.${system}.beherbergung-frontend-assets;
};
inherit
(pkgs.callPackages ./frontend/search {})
beherbergung-frontend-deps
updateFrontendDeps
beherbergung-frontend-assets
;
};
apps.${system} = {
# Run the VM with `nixos run .#vm`
vm = {
type = "app";
program = let
config = self.nixosConfigurations.vm.config;
in "${config.system.build.vm}/bin/run-${config.networking.hostName}-vm";
};
};
checks.${system} = {
format =
pkgs.runCommandNoCC "treefmt" {
nativeBuildInputs = linters;
} ''
# keep timestamps so that treefmt is able to detect mtime changes
cp --no-preserve=mode --preserve=timestamps -r ${self} source
cd source
HOME=$TMPDIR treefmt --fail-on-change
touch $out
'';
nixos-test = import ./deployment/tests/nixos-test.nix {
inherit pkgs;
makeTest = import (pkgs.path + "/nixos/tests/make-test-python.nix");
beherbergung-module = self.nixosModules.beherbergung;
};
deadnix =
pkgs.runCommandNoCC "deadnix" {
nativeBuildInputs = [deadnix.packages.${system}.deadnix];
} ''
deadnix -f ${self}
touch $out
'';
};
devShell.${system} = pkgs.mkShell {
nativeBuildInputs =
[
pkgs.leiningen
pkgs.yarn
pkgs.hivemind
pkgs.nodejs
pkgs.entr
pkgs.yarn2nix
nixos-shell.packages.${system}.nixos-shell
]
++ linters;
# disable https://nextjs.org/telemetry
NEXT_TELEMETRY_DISABLED = "1";
# fix ci failure by disabling nobuildPhase
# can be removed in NixOS 22.05
phases = [];
dontUnpack = true;
installPhase = "touch $out";
shellHook = ''
export PATH=${self.packages.${system}.beherbergung-frontend-deps}/libexec/beherbergung/node_modules/.bin:$PATH
'';
};
nixosModules = {
beherbergung = import ./deployment/modules/beherbergung.nix {
inherit (self.packages.${system}) beherbergung-fullstack;
};
beherbergung-demo = import ./deployment/modules/beherbergung-demo.nix;
};
nixosConfigurations = {
# use nixos-shell --flake .#vm
vm = lib.makeOverridable nixpkgs.lib.nixosSystem {
inherit system;
modules = [
self.nixosModules.beherbergung
self.nixosModules.beherbergung-demo
# dummy value to make ci happy
{
boot.loader.systemd-boot.enable = true;
fileSystems."/" = {
device = "/dev/disk/by-uuid/00000000-0000-0000-0000-000000000000";
fsType = "btrfs";
};
}
# allow port 4000 from host machine
({modulesPath, ...}: {
imports = [
(modulesPath + "/virtualisation/qemu-vm.nix")
];
# port forward backend
virtualisation.forwardPorts = [
{
host.port = 4000;
guest.port = 4000;
}
];
networking.firewall.allowedTCPPorts = [4000];
})
];
};
beherbergung-demo = nixpkgs.lib.nixosSystem (lib.mergeAttrs commonAttrs {
modules =
commonModules
++ [
./deployment/hosts/beherbergung-demo/configuration.nix
self.nixosModules.beherbergung
self.nixosModules.beherbergung-demo
];
});
beherbergung-lifeline = nixpkgs.lib.nixosSystem (lib.mergeAttrs commonAttrs {
modules =
commonModules
++ [
sops-nix.nixosModules.sops
./deployment/hosts/beherbergung-lifeline/configuration.nix
./deployment/modules/nginx/beherbergung-broenradio.nix
#./deployment/modules/binarycache/client.nix
#./deployment/modules/binarycache/server.nix
#./deployment/modules/monitoring/server.nix
];
});
beherbergung-warhelp = nixpkgs.lib.nixosSystem (lib.mergeAttrs commonAttrs {
modules =
commonModules
++ [
./deployment/hosts/beherbergung-warhelp/configuration.nix
];
});
};
hydraJobs = with nixpkgs.lib; let
hydraJobs = pkgs:
mapAttrs (_: hydraJob) (
nixpkgs.lib.filterAttrs (
_: pkg:
pkg ? meta
)
pkgs
);
in {
checks = hydraJobs self.checks.x86_64-linux;
packages = hydraJobs self.packages.x86_64-linux;
nixosConfigurations =
mapAttrs (
_: nixos:
hydraJob nixos.config.system.build.toplevel
)
self.nixosConfigurations;
};
};
}